# gnuplot 5.1 (CVS)
reset
set terminal svg size 600,480 fname 'Verdana,sans-serif bold' fsize 18 lw 5
unset key
set grid lt 1 lc rgb 0xAAAAAA lw .5
set border 3 lw .75
set tics nomirror
set xdata time
set timefmt  '%Y-%m-%d'
set format x '%Y-%m-%d'
set autoscale fix
set xtics 60*60*24*14 nomirror rotate by 45 right

set for [i=1:4] style line i ps .75 pt 7
set style line 1 lc rgb 0x0000FF dt 2
set style line 2 lc rgb 0x0000FF
set style line 3 lc rgb 0xFF0000 dt 2
set style line 4 lc rgb 0xFF0000

NA = '*'
do for[data in 'ebola_guinea2014 ebola_liberia2014 ebola_sierraleone2014'] {
  set output data.'.svg'
  set yrange [0:]
  plot data.'.txt' \
        u 1:(strcol(2) eq NA || strcol(3) eq NA || strcol(4) eq NA ? $8 : ($2+$3+$4)) ls 1 w lines, \
    ''  u 1:2 ls 2 w linespoints, \
    ''  u 1:(strcol(5) eq NA || strcol(6) eq NA || strcol(7) eq NA ? $9 : ($5+$6+$7)) ls 3 w lines, \
    ''  u 1:5 ls 4 w linespoints

  set output data.'_log.svg'
  unset yrange
  set logscale y
  replot
  unset logscale y